/**
 * 3D Pixelation
 * by Lukasz Karluk.
 * 
 * A video image is captured, pixalated and its pixels displayed
 * in blocks on a 3d plane with height proportional to their brightness.
 * 
 */
 
 
import processing.video.*;
import processing.opengl.*;

// Size of each cell in the grid
int blockSize = 10;
int cols;
int rows;
Block[][] aBlocks;
float nmx, nmy;

// Variable for capture device
Capture video;


void setup()
{
  size(800, 600, OPENGL);
  frameRate(30);

  colorMode(RGB,255,255,255);

  //set up columns and rows
  cols = int(round(width/blockSize));
  rows = int(round(height/blockSize));
  aBlocks = new Block[cols][rows];
  
  // init blocks.
  for(int i=0; i<aBlocks.length; i++)
  {
    for(int j=0; j<aBlocks[i].length; j++)
    {
      int x = i*blockSize;
      int y = j*blockSize;
      Block b = new Block(x,y,blockSize,blockSize);
      aBlocks[i][j] = b;
    }
  }

  // Using the default capture device
  video = new Capture(this, 200, 150, 30);
}

void captureEvent(Capture camera)
{
  camera.read();
}

void draw()
{ 
  background(0);
  
  float axSwing = 1 - mouseX/float(width)*2;          // values range from 1 to -1 when mouse is moved across the x-axis.
  //float aySwing = 1 - mouseY/float(height);
  float xSwing = mouseX/float(width)*float(width);
  float zSwing = -width/4*cos(axSwing);
  rotateY(PI/2 * axSwing);
  translate(0,0,zSwing);
  
  
  // Begin loop for columns
  for ( int i = 0; i < cols;i++) 
  {
    // Begin loop for rows
    for ( int j = 0; j < rows;j++) 
    {
      int x = i*blockSize;                                 // x position on screen
      int y = j*blockSize;                                 // y position on screen
      int vx = int(round(x * video.width / width));        // x video pixel
      int vy = int(round(y * video.height / height));      // y video pixel
      int loc = (video.width - vx - 1) + vy * video.width; // Reversing x to mirror the image
      color c = video.pixels[loc];
      Block b = aBlocks[i][j];
      b.update(c);
    }
  }
}


class Block
{
  int x, y, w, h;
  float b = 0;
  
  Block(int xVal, int yVal, int wVal, int hVal)
  {
    x = xVal;
    y = yVal;
    w = wVal;
    h = hVal;
  }
  
  void update(int c)
  {
    float bNew = 1.0-(brightness(c)/255.0f);
    b = b + (bNew-b)/10;                             //easing
    pushMatrix();
    translate(0, 0, b*200);
    //println(x+","+y+","+w+","+h);
    fill(c);
    noStroke();
    rect(x,y,w,h);
    popMatrix();
  }
}